Ардуино-спидометр.

Как снять показания спидометра ардуиной?
Подключился я к штатному спидометру и стал по всякому получать с него данные:
Если измерять длину импульса или время между импульсами, то получается ужасная нелинейность, тем более инвертированая!
Если измерять количество импульсов, то тоже не очень хорошо: если мерить импульсы за 100 миллисекунд ( не говоря уже о меньшем времени ), получается очень маленькое число, то есть например, при скорости 30 кмч. показывает 4, если делать через множитель то фигня получается! А если мерить скажем за одну секунду, то время отображения получается слишком большим, едешь 40 кмч. нажал на газ, а скорость по прежнему 40 и только чуть позже показывает реальную скорость!
Уф, понаписал .....извиняюсь за многословие)))))
Может кто подскажет как сделать лучше?

Цитата:

---

Сообщение от mebitek

... то получается ужасная нелинейность...

---

Так мир имеет не очень много линейности :) Чем гипербола хуже прямой? Автомобиль - жутко инертное тело и скорость меняется очень плавно. Там в районе 6 импульсов на оборот колеса.

Я делал на Arduino блок управления круиз-контролем.
Датчик скорости у меня стоит 6-ти импульсный, т.е. когда я проезжаю 1 метр, он производит 6-ть импульсов.
Я делал замер подряд длительности единиц и нулей при одном обороте датчика - получаем время, за которое мы проехали 1 метр (далее для перевода в км/ч - простая математика).
Для исключения влияния ошибок, я делал замер скорости за 3 оборота датчика подряд, далее делил на 3.
Как-то так...

Спасибо!!!
А можешь кусок кода выложить?

PHP код:

---

// Вспомогательная процедура - Считывание с датчика текущей скорости
void GetSpeed() {  
unsigned long DurImpSp0;     // Длительность отрицательного импульса
unsigned long DurImpSp1;     // Длительность положительного импульса
unsigned long DurImpSpAll;    // Длительность импульсов за 1 оборот
  
  for (int i = 0; i < 6; i++) {              // На сколько импульсов датчик скорости
    DurImpSp1 = pulseIn(BtnSpeed, HIGH, 20000);  // Считывание длительности положительного импульса
    DurImpSp0 = pulseIn(BtnSpeed, LOW, 20000);   // Считывание длительности отрицательного импульса    
    DurImpSpAll = DurImpSpAll + DurImpSp1 + DurImpSp0; // Складываем
  }  
  
  DurImpSpAll = (3600000 / DurImpSpAll); // Перевод в км/ч
  DurImpSpAll = DurImpSpAll - DurImpSpAll * 90 / 1000;  // Учитываем процент погрешности (определяется экспериментально)
 
  if (DurImpSpAll <= 0) { // Если скорость менее 0 - значит 0
    ValSpCurr = 0;
  }else{
    ValSpCurr = DurImpSpAll;
  }

  Serial.print("Speed = ");
  Serial.println(ValSpCurr);  
  
} 


---

прошу ногами не пинать, конструктивная критика кода приветствуется

ValSpCurr - глобальная переменная int

Цитата:

---

Сообщение от BasiC

[HTML]// Вспомогательная процедура - Считывание с датчика текущей скорости...

---

1. Если экономить (для других подпрограмм) память, то переменную можно попробовать в 1 байт сделать: 255км/ч с точностью 1км/ч - вполне даже для Феррари достаточно.
2. pulseIn(pin, value, timeout= 20000 - по-моему это секунды и их надо 1 сделать. Что-то типа DurImpSp1 = byte(pulseIn(BtnSpeed, HIGH, 1));
2. С датчика идёт 50% меандр. Считывать обе половинки по отдельности, мне кажется, излишне.
3. По-моему можно всё и в одном импульсе сделать - не делать 6 раз. Насколько мне известно, там используются интегральный микрухи - усилители-дескриминаторы сигнала с датчика Холла со встроенным подавлением "дребезга". Поэтому можно и не усреднять.
Будет не 360000/..., а 30000/... ну или точнее сделать по опыту. Коэффициент - это правильно, учитывает разного диаметра резину.

Цитата:

---

Сообщение от edw123

1. Если экономить (для других подпрограмм) память, то переменную можно попробовать в 1 байт сделать: 255км/ч с точностью 1км/ч - вполне даже для Феррари достаточно.
2. pulseIn(pin, value, timeout= 20000 - по-моему это секунды и их надо 1 сделать. Что-то типа DurImpSp1 = byte(pulseIn(BtnSpeed, HIGH, 1));
2. С датчика идёт 50% меандр. Считывать обе половинки по отдельности, мне кажется, излишне.
3. По-моему можно всё и в одном импульсе сделать - не делать 6 раз. Насколько мне известно, там используются интегральный микрухи - усилители-дескриминаторы сигнала с датчика Холла со встроенным подавлением "дребезга". Поэтому можно и не усреднять.
Будет не 360000/..., а 30000/... ну или точнее сделать по опыту. Коэффициент - это правильно, учитывает разного диаметра резину.

---

п.1 - согласен!
п.2 - 20000 это микросекунды ожидания завершения импульса. http://arduino.cc/en/Reference/PulseIn Можно поставить и 1 секунду, но если не будет импульсов, функция подвесит подпрограмму на эту 1 секунду.
п.3 - стОит попробовать. Я исходил из того, что чем больше замеров, тем выше точность

Насчёт коэффициента 3600000
Находится следующим образом. После всех замеров, мы получаем время в микросекундах, в течение которого совершается один оборот датчика (машина проезжает 1 метр).
Т.е. полученное значение выражен в микросекундах/метр. Чтобы перевести это значение в км/час, необходимо:
- перевернуть дробь
- умножить значение на 1000 (перевод м в км)
- поделить значение на 3600000000 (перевод микросекунд в часы)
- сокращаем 3600000000 на 1000
в итоге нехитрых математических операций получаем именно DurImpSpAll = (3600000 / DurImpSpAll)

Спасибо что написал!

Цитата:

---

Сообщение от BasiC

...чем больше замеров, тем выше точность...

---

Это не однозначно :) Чем больше замеров, тем больше усреднение, а значит точность падает, а не растёт. Но, понятное дело, если скорость изменения скорости :) заметно больше периода импульса, тогда хуже не станет. В случае спидометра автомобиля, думаю, так и есть. Даже я бы ограничил частоту вывода значения: что-нибудь 1раз/0,5сек - чтобы не моргали цифры на "спидометре". Автомобильный датчик сам по себе уже достаточно помехозащищён и если ардуино будет делать что-то ещё, кроме как считывать только сигнал спидометра, то можно освободить много времени для выполнения других, более полезных опреаций. Хотя бы кнопки считывать, или другие датчики. Ну это дело вкуса. ПРосто, как мне кажется, избыточный код.
Секунды - это я согласен, невнимательно смотрел - точно микросекунды.

Вообще получается, что pulseIn удобная функция, но не "фоновая". На прерываниях "по-правильнее" должно быть - опять-таки если ардуино что-то ещё будет делать.

вобщем сделал вот так:

PHP код:

---

#include <MsTimer2.h>
//#include <DallasTemperature.h>
//DallasTemperature tempSensor;
#include <LiquidCrystal.h>
LiquidCrystal lcd(12, 11, 7, 6, 5, 4);
unsigned long time;
unsigned long taxometr = 0;
unsigned long dinaimpulsov = 0;
unsigned long ValSpCurr = 0;
int tmp37 = 0;
int kpa = 0;
int volts = 0;
int pboost = 0;
int atmos = 0;
int senstvaz =0;
int ds; // сенсор ds18b20
int val;
int mapp;
int peakrpm = 0;
int peakspeed = 0;
int taxo = 0;
int count = 0;
float peakboost = 0;
float boost, voltage;
byte bytes[8]; 

void setup() 
 {
  lcd.begin(16, 2);
  pinMode(2, INPUT); 
  pinMode(3, INPUT); 
   // * LOW когда на порту LOW
   // * CHANGE , с LOW на HIGH и наоборот
   // * RISING  с LOW на HIGH
   // * FALLING  с HIGH на LOW
  attachInterrupt(0, int_on, RISING);
  //attachInterrupt(1, inton, FALLING);
  MsTimer2::set(30000, flash); // таймер будет срабатывать через каждые 500ms 
  MsTimer2::start();//запустить таймер
  //tempSensor.begin(10);
  Serial.begin(115200);
}
void loop() 
{
  /////////////////ТАХОМЕТР///////////////////////////////////////
if (taxometr > 6000)
{
 taxo = (80000000 / taxometr);
}
else 
{
  taxo = 0;
}  
if (taxo > peakrpm) //pikrpm
  {  
    peakrpm = taxo;
  }
//////////////// СПИДОМЕТР//////////////////////////////////////
    dinaimpulsov = pulseIn(3, HIGH, 100000);  // Считывание длительности положительного импульса
    ValSpCurr = (650000 / dinaimpulsov); // Перевод в км/ч
  if (dinaimpulsov > 120000 || ValSpCurr > 350)
  {
    ValSpCurr = 0;
  } 
  if (ValSpCurr > peakspeed) //pikspeed
  {  
    peakspeed = ValSpCurr;
  }
  
/////////////////////////////////////////////////////////////////
 mapp = analogRead(2);//map-sensor 
 kpa = ((mapp*(0.0045)*(51.0)+16));// killopaskali
 boost = ((mapp*(0.0045)*(51.0)+16)) / 100 -1; //kilopaskali v bar
 atmos =map(mapp, 358, 384, 735, 780);// atmosfernoe davlenie
 if (kpa > peakboost) //pikboost
  {  
    peakboost = kpa;
    pboost = peakboost;
  }
 voltage = 14.9 / 1024.0 * analogRead(1); // volts
 volts = voltage * 10;
 val = analogRead(0);// температура воды ваз 
if (val >= 0 && val <= 269)
{
   senstvaz = map(val, 0, 269, -50, -1);
}
else if (val >= 270 && val <= 503)
{
   senstvaz = map(val, 270, 503, 0, 19) + 2;
}
else if (val >= 504 && val <= 821)
{
   senstvaz = map(val, 504, 821, 20, 55) + 2;
}
else if (val >= 822 && val <= 875)
{
   senstvaz = map(val, 822, 875, 56, 65) + 2;
}
else if (val >= 876 && val <= 930)
{
   senstvaz = map(val, 876, 930, 66, 80) + 2;
}
else if (val >= 931 && val <= 946)
{
   senstvaz = map(val, 931, 946, 81, 85) + 2;
}
else if (val >= 947 && val <= 965)
{
   senstvaz = map(val, 947, 965, 86, 97) + 2;
}
else if (val >= 966 && val <= 1002)
{
   senstvaz = map(val, 966, 1002, 98, 126) + 2;
}
else if (val >= 1003 && val <= 1015)
{
   senstvaz = map(val, 1003, 1015, 127, 140) + 2;
}
 tmp37 = (analogRead(3) * 5.0 / 1024.0) / 0.02; // tmp37
/////////////////////////////////////////////
/*
if (digitalRead(9) <= 0)
  {
   ds = (tempSensor.getTemperature()),
   lcd.clear(), 
   lcd.print(ds),
   delay(1000);
  }
*/
if (Serial.available() > 0) //priem ot kompa
 {  
  int  inByte = Serial.read();
  if (inByte ==1) 
    {
      peakboost = 0;
      inByte =0;
    }
 }
 
if (digitalRead(8) <= 0) 
  {
  peakboost = 0; //sbros pikboosta, sbrasivati na minus
  peakrpm = 0;
  peakspeed = 0;
  lcd.clear();
 // lcd.setCursor(0, 0);
  lcd.print("PEAKS SBROS");
  delay(30);
  
  
  }
 ////////////////////////////////////////////////////////////////
  lcd.clear(); 
   lcd.setCursor(0, 0);
  //lcd.print(dinaimpulsov);
  lcd.print("V");
  lcd.print(voltage,1);
   lcd.setCursor(6, 0);
   lcd.print("B");
   lcd.print(boost);
//  lcd.print(taxometr);
  //lcd.print(" ");
 // lcd.print(mapp);
 // lcd.print(" ");
// lcd.print(atmos);      
 // lcd.print(" ");
 // lcd.print(taxo);
  lcd.setCursor(0, 1);
  lcd.print(dinaimpulsov);
  lcd.print(" ");
  lcd.print(ValSpCurr);
 // lcd.print(boost);
 // lcd.print(" ");
 // lcd.print(kpa);
 // lcd.print(" ");
 // lcd.print(pboost);
 // lcd.print(" ");
  //lcd.print(tmp37);
 //////////////////////////////////////////////////////////////////
  bytes[0]=(volts); //volts
  bytes[1]=(kpa); //turbo
  bytes[2]=(pboost); //pboost
  bytes[3]=(senstvaz); //senstvaz
  // bytes[4] = result & 255;                     
  // bytes[5] = (result & 768) >> 8;
  bytes[4] = taxo & 0xFF; // преобразовать в 4-байта  
  bytes[5] = (taxo & 0xFF00) >> 8;  
  bytes[6] = (taxo & 0xFF0000) >> 16; 
  bytes[7] = (taxo & 0xFF000000) >> 24;  
     
  Serial.write( bytes,8);      
   
 // delay(400);
   
  bytes[0] = 0;
  bytes[1] = 0;       
  bytes[2] = 0; 
  bytes[3] = 0; 
  bytes[4] = 0; 
  bytes[5] = 0;
  bytes[6] = 0;
  bytes[7] = 0;
      
}
/*
void  inton() 
{ 

} 
*/
void  int_on() 

{ 
count++; //увеличить счетчик volatile

if (count >= 4)
    {
      taxometr = micros()-time;  //время прихода 6-ти импульсов
      time = micros(); //обнулить
     // taxometrrr = count;
      count = 0;
    }  

} 

void flash() //обработка прерывания таймера
{
  
} 


---

Кстати, нашёл фото своего самодельного круизконтроля построенного на Arduino. Как будет больше свободного времени - выложу подробный отчёт:

http://s017.radikal.ru/i431/1112/83/f3e7516ff5f4t.jpg

Давай!!!!

А я вот так меряю скорость и расстояние :

PHP код:

---

const int  DsaPin = 8;    
int DsaPulseCounter = 0;  
int DsaState = 0;         
int LastDsaState = 0; 
int meters;
unsigned long  pulseTime = 0; 
unsigned long  thisTime = 0;
unsigned long  lastTime = 0;
unsigned long  mySpeed = 0;

void setup() 
{
  pinMode(DsaPin, INPUT);
  Serial.begin(9600);
}

void loop() 
{
odometer();
}

void odometer()
{
  DsaState = digitalRead(DsaPin);
  if (DsaState != LastDsaState) 
  {
    if (DsaState == HIGH) 
    {
        lastTime = thisTime;
        thisTime = micros();
        pulseTime = thisTime - lastTime;
        int mySpeed = (3600000000/pulseTime*15)/100000;
        
     DsaPulseCounter++;
     meters = DsaPulseCounter/6.66;
     Serial.println(meters, DEC);
     Serial.println(mySpeed);
    } 
  }
  LastDsaState = DsaState;
} 


---

Хоть и старая тема, но всё равно отпишусь :)
По-моему проще и надежней всего сделать так:
для одновременной реализации спидометра и одометра (первый - как следствие второго) нужно 3-4 переменных, задействовать одно внешнее прерывание и еще 3 переменных для формирования простых отрезков времени:

PHP код:

---

unsigned long cur_ms = 0; //переменная для отслеживания натикавших миллисекунд с момента пуска МК
unsigned long prev_ms = 0; //переменная для вычисления отрезков времени
int ms = 0; //сам отрезок времени
unsigned long m; //одометр, значение, по-идее, считывается из EEPROM при включении и потом туда же записывается при выключении МК
unsigned long m_temp = 0; //переменная для вычисления пройденного пути за отрезок времени
int speed = 0; //переменная для хранения скорости

void setup() {
pinMode(20, INPUT);
digitalWrite(20, HIGH);
attachInterrupt(3, odom, RISING);
}
void odom() {
    m++;
}
void loop() {
    cur_ms = millis(); //сколько прошло мс с момента включения
    ms = cur_ms - prev_ms; //сколько прошло мс с последнего срабатывания расчета
    if (ms > 500) {
        prev_ms = cur_ms; //ставим метку когда было срабатывание
        speed = (m - m_temp) * 3600 / ms; //вычисляем скорость км в час по кол-ву пройденных метров за отрезок времени ms
        m_temp = m; //ставим метку когда было вычисление
        ms=0; //обнуляем отрезок времени
    }
} 


---

или если без одометра (т.е. не сохранять/извлекать из eeprom), то чуть проще:

PHP код:

---

unsigned long cur_ms = 0; //переменная для отслеживания натикавших миллисекунд с момента пуска МК
unsigned long prev_ms = 0; //переменная для вычисления отрезков времени
int ms = 0; //сам отрезок времени
int m = 0; //пройденное расстояние
int speed = 0; //переменная для хранения скорости

void setup() {
pinMode(20, INPUT); //включаем 20й порт на Ардуино Мега2560 на чтение
digitalWrite(20, HIGH);  //включаем подтягивающий резистор
attachInterrupt(3, odom, RISING); //включаем внешнее прерывание
}
void odom() {
    m++; //добавляем 1 при каждом срабатывании
}
void loop() {
    cur_ms = millis(); //сколько прошло мс с момента включения
    ms = cur_ms - prev_ms; //сколько прошло мс с последнего расчета
    if (ms > 500) {
        prev_ms = cur_ms; //ставим метку когда было срабатывание
        speed = m * 3600 / ms; //вычисляем скорость км в час по кол-ву пройденных метров за отрезок времени ms
        m = 0; //обнуляем пройденное расстояние
        ms=0; //обнуляем отрезок времени
    }
} 


---

Множитель при вычислении скорости подбираем под свою "систему".
Если учесть, что на каждые 1,5 метра приходится примерно 5 срабатываний, а точность на скорости ниже 20км/ч не важна, то отрезки можно делать по 500мс и будет достаточно.
На 54км/ч, т.е. 15м/с - это 50 срабатываний в секунду. А при отрезке 500мс - 25 срабатываний. Т.е. может произойти 24-25 срабатываний (отклонение всегда в меньшую сторону, если нет дребезга) и погрешность будет -2,16..0 км/ч. С увеличением скорости точность увеличивается.
С учетом того, что редкий зверь разгоняется за 5с до сотни, грубо говоря за 0,5с можно добавить не более 10км/ч (а большинство машин и 5км/ч вряд-ли добавят).

ЗЫ: а можно включить прерывание по изменению ( attachInterrupt(3, odom, CHANGE); ) и тогда точность будет в 2 раза выше :)

Цитата:

---

Сообщение от melvladimir

... а можно включить прерывание по изменению ( attachInterrupt(3, odom, CHANGE); ) и тогда точность будет в 2 раза выше :)

---

А если длину импульса мерить, то до небывалых высот можно точность поднять :)

Код спидометра для 6-ти импульсного датчика скорости. 2 две переменные

PHP код:

---

unsigned long micros_sp = 0; 
volatile int sp; 

void setup(){ 
   attachInterrupt(0, speedometr, RISING);  
} 

void loop(){
   ............................
   ............................
}

void speedometr(){                
   sp = (600000.0 / (micros() - micros_sp)); //600000.0 - 6 имп./м  1000000.0 - 10 имп./м и т.д
   micros_sp = micros();
} 


---

Цитата:

---

Сообщение от Frud

Код спидометра для 6-ти импульсного датчика скорости. 2 две переменные

PHP код:

---

unsigned long micros_sp = 0; 
volatile int sp; 

void setup(){ 
   attachInterrupt(0, speedometr, RISING);  
} 

void loop(){
   ............................
   ............................
}

void speedometr(){                
   sp = (600000.0 / (micros() - micros_sp)); //600000.0 - 6 имп./м  1000000.0 - 10 имп./м и т.д
   micros_sp = micros();
} 


---

---

А теперь пожалуйста нарисуй схему подключения ардуины.

А че ее рисовать? На второй цифровой пин подаешь сигнал датчика, ограничив амплитуду сигнала до 4,5 В делителем или оптопарой и притянув вход к земле. Этот код работает с датчиками у которых прямоугольный сигнал, и частота сигнала соотносится со скоростью.

Цитата:

---

Сообщение от edw123

А если длину импульса мерить, то до небывалых высот можно точность поднять :)

---

Нее, измерение длины импульса - не вариант... нужны очень точные датчики и минимум люфта в соединениях, а то просто нагрузим проц. без улучшений :)

Цитата:

---

Сообщение от Frud

Код спидометра для 6-ти импульсного датчика скорости. 2 две переменные

PHP код:

---

unsigned long micros_sp = 0; 
volatile int sp; 

void setup(){ 
   attachInterrupt(0, speedometr, RISING);  
} 

void loop(){
   ............................
   ............................
}

void speedometr(){                
   sp = (600000.0 / (micros() - micros_sp)); //600000.0 - 6 имп./м  1000000.0 - 10 имп./м и т.д
   micros_sp = micros();
} 


---

---

Надо еще добавить проверку на обнуление micros(), а то через 70 минут обнулится и если где-то вычисленную скорость использовать, то может накосячить...

Цитата:

---

Сообщение от melvladimir

Нее, измерение длины импульса - не вариант... нужны очень точные датчики и минимум люфта в соединениях, а то просто нагрузим проц. без улучшений :)

---

А Вы разве не штатный датчик спидометра-одометра используете? Чем его точность не подходит?

Цитата:

---

Сообщение от melvladimir

Надо еще добавить проверку на обнуление micros(), а то через 70 минут обнулится и если где-то вычисленную скорость использовать, то может накосячить...

---

Этот код успешно используется на 4-х авто, в том числе и с обычными вазовскими датчиками скорости. Проверку на обнуление делать нет смысла. Используются не абсолютные значения micros(), а разница значений.

Цитата:

---

Сообщение от edw123

А Вы разве не штатный датчик спидометра-одометра используете? Чем его точность не подходит?

---

К сожалению штатного датчика у меня нет, сделал сам, но суть не в этом. Длину импульсов измерять - не вариант по нескольким причинам, одна из которых - лишняя нагрузка, а другая - разные датчики по разному работают... некоторые выдают голый меандр, т.к. мозг авто занимается всей обработкой и фильтрующие компоненты именно в нем, а некоторые - готовые "столбики".

Цитата:

---

Сообщение от Frud

Этот код успешно используется на 4-х авто, в том числе и с обычными вазовскими датчиками скорости. Проверку на обнуление делать нет смысла. Используются не абсолютные значения micros(), а разница значений.

---

Ну вот в один из моментов разница станет отрицательной (или максимальным значением в случае с UNSIGNED переменной). Я понимаю что в большинстве случаев - не критично, но если, например, делать круиз-контроль, то такой скачок может сбить систему... короче - маленький баг, которые в одной системе не заметен, а в другой - камень преткновения...

ЗЫ: делать код, в котором присутствует пусть и маленький, но косяк - не есть хорошо, тем более на него забивать... в результате получаются бешеные Лехусы-Тойоты...

Цитата:

---

Сообщение от melvladimir

Длину импульсов измерять - не вариант по нескольким причинам, одна из которых - лишняя нагрузка

---

Оцените величину этой лишней нагрузки.

Цитата:

---

Сообщение от melvladimir

а другая - разные датчики по разному работают... некоторые выдают голый меандр, т.к. мозг авто занимается всей обработкой и фильтрующие компоненты именно в нем, а некоторые - готовые "столбики".

---

Измеряется не длина импульса, а период. Разницу осознаете? Поэтому скважность и форма импульса значения не имеет, хоть синусоида. Что такое "столбики" я не понял, но если имеются в виду аналоговые датчики, то их значения можно измерять на аналоговом входе, а мой код для импульсных датчиков, каких подавляющее большинство.

Цитата:

---

Сообщение от melvladimir

Ну вот в один из моментов разница станет отрицательной (или максимальным значением в случае с UNSIGNED переменной). Я понимаю что в большинстве случаев - не критично, но если, например, делать круиз-контроль, то такой скачок может сбить систему...

---

Что мешает использовать абсолютное значение этой разницы без учета знака? Если если система сделана с косяком и ее может сбить скачек, то нафиг такая система нужна. Такие системы делают с обязательной защитой от случайных недостоверных значений датчиков.

Только длина импульса.

Цитата:

---

Сообщение от Frud

Оцените величину этой лишней нагрузки.

Измеряется не длина импульса, а период. Разницу осознаете? Поэтому скважность и форма импульса значения не имеет, хоть синусоида. Что такое "столбики" я не понял, но если имеются в виду аналоговые датчики, то их значения можно измерять на аналоговом входе, а мой код для импульсных датчиков, каких подавляющее большинство.

---

Это я отвечал как раз по поводу замера длины имульса (PulseIn и др. способы). "Столбики" - это форма сигнала на осциллограмме. Вот чуть выше пост опять про длину импульса...

Цитата:

---

Сообщение от Frud

Что мешает использовать абсолютное значение этой разницы без учета знака? Если если система сделана с косяком и ее может сбить скачек, то нафиг такая система нужна. Такие системы делают с обязательной защитой от случайных недостоверных значений датчиков.

---

В какой-то момент "micros_sp" будет 4 миллиарда, а micros() - небольшой и тут как ни крути, а всё равно будут неверные данные и их придется исключить.
И потом, что стоит добавить мелочь в виде "if (micros_sp < micros())" ?
И еще момент - вычисления происходят в функции прерывания, т.е. пока она выполняется другие прерывания ждут. Насколько целесообразно так часто делать лишние вычисления и отбирать микросекунды у других прерываний?

А для системы, где глюк чувствителен, я использую millis(), которая обнуляется за очень большой, как для авто, промежуток времени и вычисляю скорость по сумме импульсов за период, причем в цикле.
Сразу скажу по поводу точности и усреднения - для периода обработки в 100мс и авто "7с от 0 до 100км/ч" отставание составляет менее чем на 2км/ч (в период этого самого разгона), а после 60км/ч - меньше 1км/ч, а после 90км/ч - 0,3км/ч.

Всем привет. Очень интересна данная затея. Прошу помочь со схемой. Если будет хоть какой-то рисунок ,что куда подключать и какие номиналы радиодеталей нужны буду очень признателен. Имею датчик на мосту с 2мя проводами. Удалось считать импульсы подключив по такой схеме Вложение 17691 но параллельно со штатным спидометром данные не получались. Подключил 3м провода многожильного МГТФ с сечением 0,7мм и скорость дуня уже не показывала. Помогите, ткните носом.

Понимаю уже 10 лет прошло) Но этот код который у меня заработал более менее. Экспериментально выставил 14 имп./метр скорость совпадает. Но скорость скачет в пределах 3х км и вместо нуля часто показывает 2 Км. И все же как правильно подключать датчик спидометр к мк. Подключил через оптопару. Получил не работающий штатный спидометр.

С функцией pulseIn точности особой не получится