Уроки программирования на Processing

[Chip]

Теперь привожу пример 3D куба с подгружаемой текстурой
В качестве текстуры можно взять любую картинку размером 200х200 пикселей.

PImage tex;
float rotx = PI/1.16;
float roty = rotx;
float rotz = rotx;
float rate = 0.01;


void setup() 
{
  size(640, 430, P3D);  //размер окна и 3D режим
  tex = loadImage("txtr.png");  //текстура
  textureMode(NORMALIZED);  //режим текстурирования
}

void draw() 
{
  background(100,150,204);  //цвет фона
  lights();         //светить на обьект
  noStroke();       //убрать контур
  translate(width/2.0, height/2.0);  //местоположение, ось 
  rotx += rate;    //изменяем угол
  roty += rate * 1.8; //изменяем угол
  rotz += rate * 1.5; //изменяем угол
  rotateX(rotx);   //повернуть на угол
  rotateY(roty);   //повернуть на угол
  rotateZ(rotz);   //повернуть на угол
  scale(100,30,70);  //маштабирование в процентах
  TexturedCube(tex); //вызов процедуры рисования куба
}
//********************************************
void TexturedCube(PImage tex) 
{
  beginShape(QUADS); //нарисовать квадрат
  texture(tex);      //прилепить текстуру
  
  // +Z "front" face
  vertex(-1, -1,  1, 0, 0);
  vertex( 1, -1,  1, 1, 0);
  vertex( 1,  1,  1, 1, 1);
  vertex(-1,  1,  1, 0, 1);

  // -Z "back" face
  vertex( 1, -1, -1, 0, 0);
  vertex(-1, -1, -1, 1, 0);
  vertex(-1,  1, -1, 1, 1);
  vertex( 1,  1, -1, 0, 1);

  // +Y "bottom" face
  vertex(-1,  1,  1, 0, 0);
  vertex( 1,  1,  1, 1, 0);
  vertex( 1,  1, -1, 1, 1);
  vertex(-1,  1, -1, 0, 1);

  // -Y "top" face
  vertex(-1, -1, -1, 0, 0);
  vertex( 1, -1, -1, 1, 0);
  vertex( 1, -1,  1, 1, 1);
  vertex(-1, -1,  1, 0, 1);

  // +X "right" face
  vertex( 1, -1,  1, 0, 0);
  vertex( 1, -1, -1, 1, 0);
  vertex( 1,  1, -1, 1, 1);
  vertex( 1,  1,  1, 0, 1);

  // -X "left" face
  vertex(-1, -1, -1, 0, 0);
  vertex(-1, -1,  1, 1, 0);
  vertex(-1,  1,  1, 1, 1);
  vertex(-1,  1, -1, 0, 1);

  endShape();
}