Замена ручного управления печкой

**basurman971** · 22.03.2012, 01:44

manu_245
Какашка какая не работает.
Я в шоке.
Эти кривые буковки меня с ума сводят.

PHP код:


#include <OneWire.h>

#include <DallasTemperature.h>

#include <EEPROM.h>

#include <ks0108.h>



#include "ks0108_Mega.h"  // include this for the Arduino Mega other ATmega1280 boards

#include "SystemFont5x7.h"//шрифт 5х7 

#include "legs1.h"//значек(воздух вниз)

#include "both1.h"//значек(воздух вверх-вниз)

#include "screen1.h"//значек(воздух вверх)

#include "side1.h"//значек (воздух вперед)

#include "DS1.h"//шрифт крупный(температура)

int address = 0;



#define ONE_WIRE_BUS 50 //датчики на 50 ноге

#define TEMPERATURE_PRECISION 9



OneWire oneWire(ONE_WIRE_BUS);

DallasTemperature sensors(&oneWire);



uint8_t Thermometer0[8], Thermometer1[8], Thermometer2[8], Thermometer3[8];//адреса датчиков

float temp0, temp1, temp2, temp3, temp_s=25;//t0 - двигатель, t1 - воздуховод, t2 - улица, t3 - салон, temp_s - заданая

byte bytes[8];

int err0, err1, err2, err3;

int error=0;

int vent_set=0;



#define m3_l  43 //третий влево(заслонка горячий-холодный)

#define m3_r  44 //третий вправо(заслонка горячий-холодный)

#define en  38 //enable

#define JOY 1 //АЦП джойстик







int res_dt1;//джойстик







void setup(void)

{

  

  pinMode(m3_l,OUTPUT);

  pinMode(m3_r,OUTPUT);

  pinMode(en,OUTPUT);

  digitalWrite(m3_l,LOW);

  digitalWrite(m3_r,LOW);

  digitalWrite(en,HIGH);

  sensors.begin();

  Serial.begin(115200);

 

}



void loop(void)

{ 



  res_dt1 = analogRead(JOY); // прочитать данные АЦП

  /*

  bytes[0] = analogRead(val1) & 255;

   bytes[1] = (analogRead(val1) & 768) >> 8;

   bytes[2] = analogRead(val2) & 255;

   bytes[3] = (analogRead(val2) & 768) >> 8;

   bytes[4] = analogRead(val3) & 255;

   bytes[5] = (analogRead(val3) & 768) >> 8;

   Serial.write( bytes,6);//отправляем в комп 

   */



  }



void buttons()

{

   if(res_dt1>=715 && res_dt1<=725)//temp_s++. кнопка VOL UP

{ 

  digitalWrite(m3_r,HIGH); 

} 

else digitalWrite(m3_r,LOW); 

   

if(res_dt1>=635 && res_dt1<=645)//temp_s--. кнопка VOL DOWN 

{ 

  digitalWrite(m3_l,HIGH); 

} 

else digitalWrite(m3_l,LOW);



}

Вот че получилось все равно не работает либо поворачивает мотор и до перезагрузки.

**manu_245** · 22.03.2012, 02:21

В эмуляторе проверил. Работает.

PHP код:


#define m3_l  43 //третий влево(заслонка горячий-холодный)

#define m3_r  44 //третий вправо(заслонка горячий-холодный)

#define en  38 //enable

#define val3 7 //АЦП третьего мотора

#define JOY 1 //АЦП джойстик



int res_dt1;//джойстик



void setup(void)

{

  pinMode(m3_l,OUTPUT);

  pinMode(m3_r,OUTPUT);

  pinMode(en,OUTPUT);

  digitalWrite(m3_l,LOW);

  digitalWrite(m3_r,LOW);

  digitalWrite(en,HIGH);

  Serial.begin(115200);

}



void loop(void)

{ 

  res_dt1 = analogRead(JOY); // прочитать данные АЦП

  buttons();

  Serial.println(analogRead(val3));

}



void buttons()

{

   if(res_dt1>=715 && res_dt1<=725)//temp_s++. кнопка VOL UP

{ 

  digitalWrite(m3_r,HIGH); 

} 

else digitalWrite(m3_r,LOW); 

   

if(res_dt1>=635 && res_dt1<=645)//temp_s--. кнопка VOL DOWN 

{ 

  digitalWrite(m3_l,HIGH); 

} 

else digitalWrite(m3_l,LOW);

}

**basurman971** · 22.03.2012, 02:49

manu_245
Прикольно и правда работает.
Ниче не понимаю.Эт называется гляжу в книгу вижу фигу.
Serial.begin(115200);-это важная весч?
buttons();
Serial.println(analogRead(val3));и это
остальное один в один

**basurman971** · 22.03.2012, 03:11

manu_245
СПАСИБО!
Ниче не понимай,но работает.
Гений ёмаё.
Сам исче долго кипел бы,блин,тяжело жить с деревянной головой.
Вечером попробую это дело к большой присобачить.
Вобчем то мне от заслонки не много надо было,только чтоб поворачивалась сколько температуру выбрал.
Исче раз спасибо.

**fox-explorer** · 22.03.2012, 12:58

Пришла мысля, возник вопрос. А ардуина с тач-скрином может работать?
В том плане если в автономном режиме без компа перед lcd поставить, и
не надо джостика!

**basurman971** · 22.03.2012, 13:17

Не лучше энкодер вместо кнопок температуры.
Вроде сподручней управлять.

**basurman971** · 22.03.2012, 13:35

fox-explorer
http://robocraft.ru/blog/366.html

**manu_245** · 22.03.2012, 14:45

Если ардуино использовать одновременно как контроллер тачскрина, то при выключенном компьютере можно будет управлять климатом через тач, если еще картинку вывести. Вот http://www.compcar.ru/forum/showthre...ED%E8%F2%EE%F0

**basurman971** · 22.03.2012, 22:55

manu_245
Странно.
Скетч из 72 поста работает как часы.
Пробую подставлять в свой и тишина.

PHP код:


#include <OneWire.h>

#include <DallasTemperature.h>

#include <EEPROM.h>

#include <ks0108.h>



#include "ks0108_Mega.h"  // include this for the Arduino Mega other ATmega1280 boards

#include "SystemFont5x7.h"//шрифт 5х7 

#include "legs1.h"//значек(воздух вниз)

#include "both1.h"//значек(воздух вверх-вниз)

#include "screen1.h"//значек(воздух вверх)

#include "side1.h"//значек (воздух вперед)

#include "DS1.h"//шрифт крупный(температура)

int address = 0;



#define ONE_WIRE_BUS 50 //датчики на 50 ноге

#define TEMPERATURE_PRECISION 9



OneWire oneWire(ONE_WIRE_BUS);

DallasTemperature sensors(&oneWire);



uint8_t Thermometer0[8], Thermometer1[8], Thermometer2[8], Thermometer3[8];//адреса датчиков

float temp0, temp1, temp2, temp3, temp_s=25;//t0 - двигатель, t1 - воздуховод, t2 - улица, t3 - салон, temp_s - заданая

byte bytes[8];

int err0, err1, err2, err3;

int error=0;

int vent_set=0;



#define m1_l  39 //первый влево 

#define m1_r  40 //первый вправо

#define m2_l  41 //второй влево (боковые)

#define m2_r  42 //второй вправо(стекло)

#define m3_l  43 //третий влево(заслонка горячий-холодный)

#define m3_r  44 //третий вправо(заслонка горячий-холодный)

#define en  38 //enable

#define JOY 1 //АЦП джойстик

#define val2 5 //АЦП второго мотора

#define val1 6 //АЦП первого мотора

#define val3 7 //АЦП третьего мотора

#define vent 31 //ШИМ вентилятора



int res_dt1;//джойстик

//int min_3 = 115; //(заслонка горячий-холодный)

//int max_3 = 950; //(заслонка горячий-холодный)

int min_2 = 185; //боковые

int max_2 = 450; //стекло

int centr_1 = 310; //среднее первый

int min_1 = 310; //ноги

int max_1 = 490; //ноги закрыто

int centr_2 = 370; //среднее второй

int vent_s=3;

int vent_speed=3;

int t=5, f=0;

int flow=5;

unsigned long time;





void setup(void)

{

  pinMode(m1_l,OUTPUT); 

  pinMode(m1_r,OUTPUT);

  pinMode(m2_l,OUTPUT); 

  pinMode(m2_r,OUTPUT);

  pinMode(m3_l,OUTPUT);

  pinMode(m3_r,OUTPUT);

  pinMode(en,OUTPUT);

  pinMode(vent,OUTPUT);

  digitalWrite(m1_l,LOW);

  digitalWrite(m1_r,LOW);

  digitalWrite(m2_l,LOW);

  digitalWrite(m2_r,LOW);

  digitalWrite(m3_l,LOW);

  digitalWrite(m3_r,LOW);

  digitalWrite(en,HIGH);

  digitalWrite(vent,LOW );

  sensors.begin();

  Serial.begin(115200);

  TCCR2B = TCCR2B & 0b11111000 | 0x04;



  //devices=sensors.getDeviceCount();//считаем сколько датчиков подключено  



  if (!sensors.getAddress(Thermometer0, 0)) err0=1;//ошибка. нет датчика 0 - двигатель

  if (!sensors.getAddress(Thermometer1, 1)) err1=1;//ошибка. нет датчика 1 - воздуховод

  if (!sensors.getAddress(Thermometer2, 2)) err2=1;//ошибка. нет датчика 2 - улица

  if (!sensors.getAddress(Thermometer3, 3)) err3=1;//ошибка. нет датчика 3 - салон



  sensors.setResolution(Thermometer0, 9);

  sensors.setResolution(Thermometer1, 9);

  sensors.setResolution(Thermometer2, 9);

  sensors.setResolution(Thermometer3, 9);



  GLCD.Init(NON_INVERTED);   // initialise the library, non inverted writes pixels onto a clear screen

  GLCD.ClearScreen(); 



  GLCD.SelectFont(System5x7);

  GLCD.CursorTo(0,5);

  GLCD.Puts("OUTSIDE:");

  GLCD.CursorTo(0,6);

  GLCD.Puts("VENT SPEED:");



  /*

  if(analogRead(val1) > max_1-10 && analogRead(val2) < min_2+10) flow=2;

   if(analogRead(val1) > max_1-10 && analogRead(val2) > max_2-10) flow=0;

   if(analogRead(val1) > min_1-10 && analogRead(val1) < min_1+10) flow=1; 

    */



  temp_s = EEPROM.read(address);//читаем заданую температуру из еепром

  bytes[0] = 0xFF; 

  bytes[1] = temp_s;

  bytes[2] = flow;

  bytes[3] = 0;

  Serial.write( bytes,4);//отправляем ее в комп 

}



void loop(void)

{ 

  res_dt1 = analogRead(JOY); // прочитать данные АЦП

  /*

  bytes[0] = analogRead(val1) & 255;

   bytes[1] = (analogRead(val1) & 768) >> 8;

   bytes[2] = analogRead(val2) & 255;

   bytes[3] = (analogRead(val2) & 768) >> 8;

   bytes[4] = analogRead(val3) & 255;

   bytes[5] = (analogRead(val3) & 768) >> 8;

   Serial.write( bytes,6);//отправляем в комп 

   */

  byte a, b; 

  if (Serial.available() > 1)

  { 

    a = Serial.read();  

    b = Serial.read();

    if(a==0x64)temp_s=b;

    if(a==0xFF)f=b;

    if(a==0x78)vent_s=b*10;

   Serial.println(analogRead(val3));

  }



  analogWrite(vent, vent_s);//вентилятор

  buttons();

  if ((millis()-time)>500 && res_dt1 == 1023) //запуск процедур по таймеру

  {    

    time = millis();

    termometer();

  }

  motors();

  lcd(); 

  vent_speed=vent_s/17; 

}



void termometer()

{

  int m0, m1, m;

  sensors.requestTemperatures();

  temp0 = sensors.getTempC(Thermometer0);

  temp1 = sensors.getTempC(Thermometer1);

  temp2 = sensors.getTempC(Thermometer2);

  temp3 = sensors.getTempC(Thermometer3);



  if(temp3<0)

  {

    m0=1;

    temp3=-temp3;

  }

  else m0=0;



  if(temp2<0)

  {

    m1=1;

    temp2=-temp2;

  }

  else m1=0;



  m=m0*10+m1;



  bytes[0] = 0x64; //префикс

  bytes[1] = temp3; //салон

  bytes[2] = m;

  bytes[3] = temp2; //улица

  Serial.write( bytes,4);

}

 

 void motors()

{

  if(flow==0)//стекло

  {

    if (analogRead(val2)<max_2)digitalWrite(m2_r,HIGH);

    else digitalWrite(m2_r,LOW);

    if (analogRead(val1)<max_1)digitalWrite(m1_l,HIGH);

    else digitalWrite(m1_l,LOW);

  }



  if(flow==1)//в ноги

  {

    if (analogRead(val1)>min_1)digitalWrite(m1_r,HIGH);

    else digitalWrite(m1_r,LOW);

  }

  if(flow==2)//боковые

  {

    if (analogRead(val2)>min_2)digitalWrite(m2_l,HIGH);

    else digitalWrite(m2_l,LOW);

    if (analogRead(val1)<max_1)digitalWrite(m1_l,HIGH);

    else digitalWrite(m1_l,LOW);

  }

  if(flow==3)//стекло и ноги 

  {

    if (analogRead(val2)<max_2)digitalWrite(m2_r,HIGH);

    else digitalWrite(m2_r,LOW);

    if (analogRead(val1)>min_1)digitalWrite(m1_r,HIGH);

    else digitalWrite(m1_r,LOW);

  }

}



void buttons()

{ 

  

  if(res_dt1>=176 && res_dt1<=186)//кнопка SOURCE

  {

    EEPROM.write(address, temp_s);//пишем в еепром temp_set

    delay(500);

  }





  if(res_dt1>=556 && res_dt1<=566)//vent_s ++. кнопка TRACK UP

  {

    vent_s=vent_s+10;

    delay(30);

    if(vent_s > 250)vent_s=255;

    bytes[0] = 0xC8; //префикс

    bytes[1] = vent_s/10;

    bytes[2] = 0;

    bytes[3] = 0;

    Serial.write( bytes,4);

    delay(80);

  }



  if(res_dt1>=475 && res_dt1<=485)//vent_s --. кнопка TRACK DOWN

  {

    vent_s=vent_s-10;

    delay(30);

    if(vent_s <=0)vent_s=0;

    bytes[0] = 0xC8; //префикс

    bytes[1] = vent_s/10;

    bytes[2] = 0;

    bytes[3] = 0;

    Serial.write( bytes,4);

    delay(80);

  }



  if((res_dt1>=843 && res_dt1<=853) || f==0)// на стекло. кнопка MODE

  {

    flow=0;

    f=5;

    bytes[0] = 0x4B;

    bytes[1] = flow;

    bytes[2] = 0;

    bytes[3] = 0; 

    Serial.write( bytes,4);

    delay(80);

  }



  if((res_dt1>=401 && res_dt1<=411) || f==1)//в ноги. кнопка FILE

  {

    flow=1;

    f=5;

    bytes[0] = 0x4B;

    bytes[1] = flow;

    bytes[2] = 0;

    bytes[3] = 0; 

    Serial.write( bytes,4);

    delay(80);

  }



  if((res_dt1>=784 && res_dt1<=794) || f==2)//боковые. кнопка SEL

  {

    flow=2;

    f=5;

    bytes[0] = 0x4B;

    bytes[1] = flow;

    bytes[2] = 0;

    bytes[3] = 0; 

    Serial.write( bytes,4);

    delay(80);

  }



  if((res_dt1>=307 && res_dt1<=327) || f==3)//на стекло и в ноги. кнопка ATT

  {

    flow=3;

    f=5;

    bytes[0] = 0x4B;

    bytes[1] = flow; 

    bytes[2] = 0;

    bytes[3] = 0;

    Serial.write( bytes,4);

    delay(80);

  }

}



void lcd()

{



  GLCD.SelectFont(DS);

  GLCD.CursorTo(0,0);

  GLCD.PrintNumber(temp3);

  GLCD.Puts("/  ");

  if(temp_s>=10)GLCD.CursorTo(5,0);

  else GLCD.CursorTo(6,0);

  GLCD.PrintNumber(temp_s);

  GLCD.Puts("/");

  GLCD.SelectFont(System5x7);

  GLCD.CursorTo(8,5);

  GLCD.PrintNumber(temp2);

  GLCD.Puts(" C");



  int i=0;

  for(i=0;i<vent_speed;i++)

  {

    GLCD.CursorTo(i,7);

    GLCD.Puts("*");

  }

  int j=0;

  for(j=vent_speed;j<15;j++)

  {

    GLCD.CursorTo(j,7);

    GLCD.Puts(" ");

  }



  if(flow==0)GLCD.DrawBitmap(screen, 96,32, BLACK);

  if(flow==1)GLCD.DrawBitmap(legs, 96,32, BLACK);

  if(flow==2)GLCD.DrawBitmap(side, 96,32, BLACK);

  if(flow==3)GLCD.DrawBitmap(both, 96,32, BLACK); 

}

И почемуто на моем скетче стал сильно греться драйвер
напруги все проверил все в норме стоит залить проверочный
все огонь.

**manu_245** · 25.03.2012, 14:43

Скетч из последнего поста не содержит управления 3-м приводом, остальные должны работать. Связи между нагревом и скетчем я не вижу. Возможно неправильно подключены приводы.

Минусом всей этой схемы является то, что обязательно надо проверять направление.
То есть, если пишем, например,

PHP код:


if (analogRead(val2)<max_2)digitalWrite(m2_r,HIGH);

else digitalWrite(m2_r,LOW);

, необходимо обязательно поверить, что при m2_r,HIGH значение АЦП увеличивается, а не уменьшается! Иначе analogRead(val2) всегда будет <max_2, и привод упрется, но будет продолжать крутить.

Чтобы прописать заслонку температуры необходимо знать АЦП в крайних положениях и, главное, как ее положение должно быть связано с температурой или каким-либо другим параметром. Скорее всего эта зависимость подбирается по месту на конкретной заслонке.
Вот пока вариант с управлением заслонкой джойстиком. ЖК отключен.
Предположительно с экраном проблема. Библиотека то не под мегу переписана.
Как подключен ЖК? Есть схема? Регистр применяется? На меге без регистра лучше даже. Это вынужденная мера была для экономии ног.

PHP код:


#include <OneWire.h>

#include <DallasTemperature.h>

#include <EEPROM.h>



int address = 0;



#define ONE_WIRE_BUS 50 //датчики на 50 ноге

#define TEMPERATURE_PRECISION 9



OneWire oneWire(ONE_WIRE_BUS);

DallasTemperature sensors(&oneWire);



uint8_t Thermometer0[8], Thermometer1[8], Thermometer2[8], Thermometer3[8];//адреса датчиков

float temp0, temp1, temp2, temp3, temp_s=25;//t0 - двигатель, t1 - воздуховод, t2 - улица, t3 - салон, temp_s - заданая

byte bytes[8];

int err0, err1, err2, err3;

int error=0;

int vent_set=0;



#define m1_l  39 //первый влево 

#define m1_r  40 //первый вправо

#define m2_l  41 //второй влево (боковые)

#define m2_r  42 //второй вправо(стекло)

#define m3_l  43 //третий влево(заслонка горячий-холодный)

#define m3_r  44 //третий вправо(заслонка горячий-холодный)

#define en  38 //enable

#define JOY 1 //АЦП джойстик

#define val2 5 //АЦП второго мотора

#define val1 6 //АЦП первого мотора

#define val3 7 //АЦП третьего мотора

#define vent 31 //ШИМ вентилятора



int res_dt1;//джойстик

int min_3 = 115; //(заслонка горячий-холодный)

int max_3 = 950; //(заслонка горячий-холодный)

int min_2 = 185; //боковые

int max_2 = 450; //стекло

int centr_1 = 310; //среднее первый

int min_1 = 310; //ноги

int max_1 = 490; //ноги закрыто

int centr_2 = 370; //среднее второй

int vent_s=3;

int vent_speed=3;

int t=5, f=0;

int flow=5;

unsigned long time;





void setup(void)

{

  pinMode(m1_l,OUTPUT); 

  pinMode(m1_r,OUTPUT);

  pinMode(m2_l,OUTPUT); 

  pinMode(m2_r,OUTPUT);

  pinMode(m3_l,OUTPUT);

  pinMode(m3_r,OUTPUT);

  pinMode(en,OUTPUT);

  pinMode(vent,OUTPUT);

  digitalWrite(m1_l,LOW);

  digitalWrite(m1_r,LOW);

  digitalWrite(m2_l,LOW);

  digitalWrite(m2_r,LOW);

  digitalWrite(m3_l,LOW);

  digitalWrite(m3_r,LOW);

  digitalWrite(en,HIGH);

  digitalWrite(vent,LOW );

  sensors.begin();

  Serial.begin(115200);

  TCCR2B = TCCR2B & 0b11111000 | 0x04;



  //devices=sensors.getDeviceCount();//считаем сколько датчиков подключено  



  if (!sensors.getAddress(Thermometer0, 0)) err0=1;//ошибка. нет датчика 0 - двигатель

  if (!sensors.getAddress(Thermometer1, 1)) err1=1;//ошибка. нет датчика 1 - воздуховод

  if (!sensors.getAddress(Thermometer2, 2)) err2=1;//ошибка. нет датчика 2 - улица

  if (!sensors.getAddress(Thermometer3, 3)) err3=1;//ошибка. нет датчика 3 - салон



  sensors.setResolution(Thermometer0, 9);

  sensors.setResolution(Thermometer1, 9);

  sensors.setResolution(Thermometer2, 9);

  sensors.setResolution(Thermometer3, 9);



  temp_s = EEPROM.read(address);//читаем заданую температуру из еепром

  bytes[0] = 0xFF; 

  bytes[1] = temp_s;

  bytes[2] = flow;

  bytes[3] = 0;

  Serial.write( bytes,4);//отправляем ее в комп 

}



void loop(void)

{ 

  res_dt1 = analogRead(JOY); // прочитать данные АЦП

  /*

   bytes[0] = analogRead(val1) & 255;

   bytes[1] = (analogRead(val1) & 768) >> 8;

   bytes[2] = analogRead(val2) & 255;

   bytes[3] = (analogRead(val2) & 768) >> 8;

   bytes[4] = analogRead(val3) & 255;

   bytes[5] = (analogRead(val3) & 768) >> 8;

   Serial.write( bytes,6);//отправляем в комп 

  */

  byte a, b; 

  if (Serial.available() > 1)

  { 

    a = Serial.read();  

    b = Serial.read();

    if(a==0x64)temp_s=b;

    if(a==0xFF)f=b;

    if(a==0x78)vent_s=b*10;

  }



  analogWrite(vent, vent_s);//вентилятор

  buttons();

  if ((millis()-time)>500 && res_dt1 == 1023) //запуск процедур по таймеру

  {    

    time = millis();

    termometer();

  }

  motors();

  vent_speed=vent_s/17; 

}



void termometer()

{

  sensors.requestTemperatures();

  temp0 = sensors.getTempC(Thermometer0);

  temp1 = sensors.getTempC(Thermometer1);

  temp2 = sensors.getTempC(Thermometer2);

  temp3 = sensors.getTempC(Thermometer3);



  bytes[0] = 0x64; //префикс

  bytes[1] = temp3+40; //салон

  bytes[2] = 0;

  bytes[3] = temp2+40; //улица

  Serial.write( bytes,4);

}

 

 void motors()

{

  if(flow==0)//стекло

  {

    if (analogRead(val2)<max_2)digitalWrite(m2_r,HIGH);

    else digitalWrite(m2_r,LOW);

    if (analogRead(val1)<max_1)digitalWrite(m1_l,HIGH);

    else digitalWrite(m1_l,LOW);

  }



  if(flow==1)//в ноги

  {

    if (analogRead(val1)>min_1)digitalWrite(m1_r,HIGH);

    else digitalWrite(m1_r,LOW);

  }

  if(flow==2)//боковые

  {

    if (analogRead(val2)>min_2)digitalWrite(m2_l,HIGH);

    else digitalWrite(m2_l,LOW);

    if (analogRead(val1)<max_1)digitalWrite(m1_l,HIGH);

    else digitalWrite(m1_l,LOW);

  }

  if(flow==3)//стекло и ноги 

  {

    if (analogRead(val2)<max_2)digitalWrite(m2_r,HIGH);

    else digitalWrite(m2_r,LOW);

    if (analogRead(val1)>min_1)digitalWrite(m1_r,HIGH);

    else digitalWrite(m1_r,LOW);

  }

}



void buttons()

{ 

  

  if(res_dt1>=176 && res_dt1<=186)//кнопка SOURCE

  {

    EEPROM.write(address, temp_s);//пишем в еепром temp_set

    delay(500);

  }

  

  if(res_dt1>=715 && res_dt1<=725)//temp_s++. кнопка VOL UP

  {

    digitalWrite(m3_r,HIGH); 

  }

  else digitalWrite(m3_r,LOW);

    

  if(res_dt1>=635 && res_dt1<=645)//temp_s--. кнопка VOL DOWN

  {

    digitalWrite(m3_l,HIGH);

  }

  else digitalWrite(m3_l,LOW);

  

  

  if(res_dt1>=556 && res_dt1<=566)//vent_s ++. кнопка TRACK UP

  {

    vent_s=vent_s+10;

    delay(30);

    if(vent_s > 250)vent_s=255;

    bytes[0] = 0xC8; //префикс

    bytes[1] = vent_s/10;

    bytes[2] = 0;

    bytes[3] = 0;

    Serial.write( bytes,4);

    delay(80);

  }



  if(res_dt1>=475 && res_dt1<=485)//vent_s --. кнопка TRACK DOWN

  {

    vent_s=vent_s-10;

    delay(30);

    if(vent_s <=0)vent_s=0;

    bytes[0] = 0xC8; //префикс

    bytes[1] = vent_s/10;

    bytes[2] = 0;

    bytes[3] = 0;

    Serial.write( bytes,4);

    delay(80);

  }



  if((res_dt1>=843 && res_dt1<=853) || f==0)// на стекло. кнопка MODE

  {

    flow=0;

    f=5;

    bytes[0] = 0x4B;

    bytes[1] = flow;

    bytes[2] = 0;

    bytes[3] = 0; 

    Serial.write( bytes,4);

    delay(80);

  }



  if((res_dt1>=401 && res_dt1<=411) || f==1)//в ноги. кнопка FILE

  {

    flow=1;

    f=5;

    bytes[0] = 0x4B;

    bytes[1] = flow;

    bytes[2] = 0;

    bytes[3] = 0; 

    Serial.write( bytes,4);

    delay(80);

  }



  if((res_dt1>=784 && res_dt1<=794) || f==2)//боковые. кнопка SEL

  {

    flow=2;

    f=5;

    bytes[0] = 0x4B;

    bytes[1] = flow;

    bytes[2] = 0;

    bytes[3] = 0; 

    Serial.write( bytes,4);

    delay(80);

  }



  if((res_dt1>=307 && res_dt1<=327) || f==3)//на стекло и в ноги. кнопка ATT

  {

    flow=3;

    f=5;

    bytes[0] = 0x4B;

    bytes[1] = flow; 

    bytes[2] = 0;

    bytes[3] = 0;

    Serial.write( bytes,4);

    delay(80);

  }

}

Тема: Замена ручного управления печкой

Опции темы

Поиск по теме

Отображение

Re: Замена ручного управления печкой

Re: Замена ручного управления печкой

Re: Замена ручного управления печкой

Re: Замена ручного управления печкой

Re: Замена ручного управления печкой

Re: Замена ручного управления печкой

Re: Замена ручного управления печкой

Re: Замена ручного управления печкой

Re: Замена ручного управления печкой

Re: Замена ручного управления печкой

Информация о теме

Пользователи, просматривающие эту тему

Ваши права