Автоматическое освещение лестницы

[IgorSokol]

Видео чуть позже выложу. нечем снимать пока...
скетч вот. при наступлении темноты включает первую и последнюю ступеньку.

#include "Tlc5940.h"
#include "Ultrasonic.h"

TLC_CHANNEL_TYPE channel;

//Устанавливаем контакты для первого датчика
#define  TRIG_PIN  5
#define  ECHO_PIN  6
//Устанавливаем контакты для второго датчика
#define  TRIG2_PIN  7
#define  ECHO2_PIN  8
//Определяем первый датчик
Ultrasonic OurModuleUp(TRIG_PIN, ECHO_PIN);
//Определяем второй датчик
Ultrasonic OurModuleDown(TRIG2_PIN, ECHO2_PIN);

const unsigned char DataPin = 0;
const unsigned char clockPin = 1;

// Диапазон при котором сработает сенсор
const float minBottomIn = 33.0f;
const float minTopIn = minBottomIn;

//задержка выстрела сенсоров
const long pingReadDelay = 50;

// задержка между ступеньками
const long lightSpacing = 150;
//задержка свечения всей лестницы
const long lightHold = 10000;
//количество ступенек
const byte kol_st = 9;
//маскимальная яркость
const long maxLight = 4095;
//задержка ШИМ
const int delPWM = 5;
//шаг наращивания яркости
const int stepPWM = 50;

//переменная под датчик освещенности
int val;

void setup()
{
  Tlc.init();
 
  Serial.begin(9600);        
  pinMode(DataPin, OUTPUT);
  pinMode(clockPin, OUTPUT);      
 }

void loop()
{
     val = analogRead(0);
    //Проверяем освещенность в помещении

   if (val>=1020){
     
     //зажигаем первую и последнюю ступеньку на 5% от максимума
      Tlc.set(0,200);
      Tlc.set(kol_st-1,200);  
      Tlc.update();

     //проверяем дачтики, сначала верхний, потом нижний
     if((OurModuleUp.Ranging(INC) < minTopIn) && (OurModuleUp.Ranging(INC) > 0))
        {
          Serial.println("Top sensor tripped.");
          fadeDOWN();
        }
     if((OurModuleDown.Ranging(INC) < minTopIn) && (OurModuleDown.Ranging(INC) > 0)) {
      Serial.println("Bottom sensor tripped.");
      fadeUP();
    }
   
   }
   delay(pingReadDelay);
}

void fadeUP()
{
// Tlc.clear();
  for (int i=0; i<kol_st; i++) {
   for (int j=0; j<=maxLight; j=j+stepPWM) {
   Tlc.set(i,j);
   Tlc.update();
   delay(delPWM);
   }
    delay(lightSpacing);
  }
  delay(lightHold);
  for (int i=0; i<kol_st; i++) {
    for (int j=maxLight; j>0; j=j-stepPWM) {
     if (j<stepPWM) j=0; 
     Tlc.set(i,j);
     Tlc.update();
     delay(delPWM);
     }
    delay(lightSpacing);
  }
}

void fadeDOWN()
{
  for (int i=kol_st; i>=0; i--) {
   for (int j=0; j<=maxLight; j=j+stepPWM) {
   Tlc.set(i,j);
   Tlc.update();
   delay(delPWM);
   }
    delay(lightSpacing);
  }
  delay(lightHold);
  for (int i=kol_st; i>=0; i--) {
    for (int j=maxLight; j>0; j=j-stepPWM) {
     if (j<stepPWM) j=0; 
     Tlc.set(i,j);
     Tlc.update();
     delay(delPWM);
     }
    delay(lightSpacing);
  }
}