Парктронник

Добрый вечер всем :)

Тема не нова, хочется себе сделать парктронник. Для этого было приобретено два девайса

1. Ардуино Нано
2. Парктронник китайского производства

У парктрониика разъем который идет на дисплей состоит из 3х проводов
Обозначения проводов
GND
5+
DA

Фото платы

http://photofile.ru/photo/oops2/1158.../142096278.jpg

http://photofile.ru/photo/oops2/1158.../142096276.jpg

GND соединил с выводом GND arduino
DA соединил с выводом A1 arduino

Для анализа того что шлет парктронник на свой дисплей пробывал разные осциллографы основанные на Arduino, анализировать не возможно.

Остановился на таком варианте
Код на ардуино

PHP код:

---

byte MyBuff1[1]; 

unsigned int i=0; 
byte count =0; 
byte readVal =0;
  
void setup()   
{  
Serial.begin(115200);   
}   
void loop()   
{   
 
  for (i=0;  i < 400; i++)   
  {   
    readVal = analogRead(1)/4;
    if ( readVal > 0)
      MyBuff1[0] = 1;
    else 
      MyBuff1[0] = 0;

    Serial.write(MyBuff1,1);
  } 
}  

void LedHI()
{
  digitalWrite(13, HIGH);   // set the LED on
  delay(1000);              // wait for a second
  digitalWrite(13, LOW);    // set the LED off
  delay(1000);  
} 


---

Получил вот такой поток данных (в аттаче полный трейс) за 2 секунды работы программы

PHP код:

---

000000000000000000000000000000000000000000000000000000000000000000000
00000000000001000000000000000000000000000000000111111110110100100100111001
10110110110110111101101101101000000000000000000000000000000000000000000000
00000000000000000000000000000000000000000000000000000000000000000000000000
00000000000000000000000000000000000000000000000000000000000000000000000000
00000100000000000000000000000000000000000000000000001111111101101001001001
10001001101101101101101011011011010000000000000000000000000000000000000000
00000000000000000000000000000000000000000000000000000000000000000000000000
00000000000000000000000000000000000000000000000000000000000000000000000000
000000000000000000000000000000000000000000000000000000000 


---

Пактрониик находился в состоянии когда препятствие не отображается.

Теперь вопросы :)

1. Как мне лучше модифицировать скетч для адруино для аннализа
2. Вообще правильная ли идея ? потому как мне качется я не правильно читаю данные иц цифрового канала.
3. Кто может помочь проанализировать поток данных.


Цель данной темы получить открытый проект доступный каждому.

p.s.
Парктроник обошелся в 18 баксов

С парктроника скорее всего выходит однопроводная шина OneWire
Так что лучше подключить к цифровому входу для анализа, сигнала

Я пробывал использовать digitalRead(1)

только почему то эта функция возвращает всегда '1'
а analogRead(1)/4 возвращает число от 24 до 255 (для единицы)

---

Еще я запутался в портах ардуно :)

есть A0..A5 а есть D5,D6...

Как к этим портам обращатся в коде, перечитал хелп ардуно но так и не нашел ответ на вопрос.

alalogRead(5) читает порт А5 или D5 ?

alalogRead(5) это А5
digitalRead(5) это D5
Почитай здесь про то как считать твой сигнал http://www.compcar.ru/forum/showthread.php?t=7222

Спасибо. щас зачитаю

А фото платы, которая в дисплее, есть? Что за м/сх там стоят?

фото платы в дисплее попробую вечером сделать. Но складывается такое ощущение что надписи на микрухах затерты.

oops1, если есть возможность, запиши сигнал на компьютер через линейный вход звуковухи. Только подключать нужно через кондер (это так, на всякий случай).
В твоих трейсах есть некая нестабильность показаний, но "стартовый" пакет битов (8 единиц) явно прослеживается. Далее еще 6 байт, вот они и скачут у тебя.

Вот фото

http://photofile.ru/photo/oops2/1158.../142112223.jpg

http://photofile.ru/photo/oops2/1158.../142112226.jpg

zhserg, конденсатор какой емкости, последовательно или параллельно ?

на mp3car читал ветку где Руби (кажется) описывал работу двух парктронников, графики уже удалили, но словами у него написано что длительность импульса 0 и импульса 1.

Я всегда думал что 0 это отсутствие сигнала, а получается что импульс разной дины.
Возможно в моих пакетах и нули и единица обозначаются как "1".

Дело осложняется тем что нету осцилографа, пробовал осциллограф на ардуно, достойно проги не нашел на которой было бы все видно.

Думаю может купить такую тему
http://cgi.ebay.com/2Msps-Sampling-R...#ht_8623wt_906

Но с другой стороны желательно обойтись малой кровью. чтобы было просто для повторения (если конечно кто нибудь захочет повторить и у меня получится :))

Сделай на ардуино логический анализатор, осциллограф читает медленно из-за аналогового порта, с цифрового порта будет читать в разы быстрее

Цитата:

---

Сообщение от oops1

zhserg, конденсатор какой емкости, последовательно или параллельно ?

---

1 мкФ или больше, последовательно.

zhserg
извиняюсь за незнание физики, а line in на звуковой не погорит ? для него вроде как максимальное напряжение 2 вольта, а тут по моим прикидкам получается около 5. может делитель еще воткнуть ?

Наверное это Chip имел ввиду
http://www.uchobby.com/index.php/200...ogic-analyzer/
http://timothytwillman.com/itp_blog/?page_id=124

нет, эта тема не прокатит. я все больше думаю о том что 0 и 1 кодируются временем. а не наличием отсутствием сигнала.

вот тут описание от рубби
http://www.mp3car.com/hardware-devel...y-pdc-usb.html

думается мне что у меня второй тип парктронника

Цитата:

---

The whole data packet of this second kit is composed by 10 half periods where the logical "0" has a time duration of about 2 mS and the logical "1" is about 5 mS, so when it is powered, a series of 10 bits will be transmitted to the display many times per second.

---

Цитата:

---

Сообщение от oops1

zhserg может делитель еще воткнуть ?

---

Естественно.

Получил такую картинку через звуковую карты используя демонстрационный режим программы Multi-Instrument 3.2


http://photofile.ru/photo/oops2/1158.../142126735.jpg

Теперь есть от чего отталкиваться при запуске логического анализатора - без его программной основы все равно не обойтись при дальнейшем развитии проекта!
oops1, к сожалению еще не смог посмотреть детально (растянуто) wav файл. Посылки повторяются?

Предлагаю воспользоваться вот этим материалом для анализатора.

zhserg, прочитал, спасибо. Но для того чтобы делать что то подобное надо понять как кодируются данные.
Пока я склоняюсь к тому что в моем сигнале это

1 = 260 микросекунд
0 = 104 микросекунд

Надо считать время.

получается мой пакет это

PHP код:

---

1111 1000 1000 1111 1111 0
1111 1000 1011 1011 1111 0
1111 1000 1001 1111 1111 0
1111 1000 1010 1111 1111 0
1111 1000 1000 1111 1111 0
1111 1000 1011 1111 1111 0
1111 1000 1001 1111 1111 0
1111 1000 1010 1111 1111 0
1111 1000 1000 1111 1111 0
1111 1000 1011 1111 1111 0
1111 1000 1001 1111 1111 0
1111 1000 1010 1111 1111 0
1111 1000 1000 1111 1111 0
1111 1000 1011 1111 1111 0
1111 1000 1001 1111 1111 0
1111 1000 1010 1111 1111 0
1111 1000 1000 1111 1111 0
1111 1000 1011 1111 1111 0
1111 1000 1001 1111 1111 0
1111 1000 1010 1111 1111 0
1111 1000 1000 1111 1111 0
1111 1000 1011 1111 1111 0
1111 1000 1001 1111 1111 0
1111 1000 1010 1111 1111 0
1111 1000 1000 1111 1111 0
1111 1000 1011 1111 1111 0 


---

пакет начинается всегда с 1111
3-я тетрада это номер датчика.

В данном пакете идет чередование информации 4-х датчиках 0 - 3 - 1 - 2

Пакет заканчивается всегда нулем

Таким образом "центральный" блок выдает только информацию с датчиков! Я, честно говоря, надеялся что там будут уже обработанные данные и будет выходить инф. для отображения.
Ну тогда нужно следующим этапом эмулировать срабатывание каждого отдельного датчика и смотреть где "зарыто" расстояние - по сути больше ничего и нужно.
p.s. Каким образом ты получил пакет, вручную по графикам?

Да вручную по граффикам опираясь на время длительности импульса

oops1, смотри скорее - у Рубби появились картинки :).

Ага сохранил себе :)

Подскажите мне по таймеру в ардуино.
так это пишется ?

PHP код:

---

byte MyBuff[800]; 
unsigned int i=0; 


#define TCNT2_Const (256-2)

void setup()   
{  

  Serial.begin(115200);   
  TIMSK2 &= ~(1<<TOIE2); //разрешения прерывания по переполнению таймера/счетчика Т2   
  TCCR2A &= ~((1<<WGM21) | (1<<WGM20));// Режим работы таймера/счетчика  
  TCCR2B &= ~(1<<WGM22);// Режим работы таймера/счетчика  
  TCCR2B |= (1<<CS20)|(1<<CS21); //(1<<CS21)|(1<<CS20)|(1<<CS22); //установка предделителя 32
  ASSR &= ~(1<<AS2);  //Выбор источника синхронизации таймера если AS2=0 от системного генератора  
  TCNT2 = TCNT2_Const; //  16000000/256/100/64=8 tcnt2=256-8=248.      
  TIMSK2 |= (1<<TOIE2);//Разрешение прерывания по переполнению Т2.
}   
void loop()   
{   

}  

SIGNAL(TIMER2_OVF_vect) 
{
    TCNT2=TCNT2_Const;
} 


---

Честно скажу - не знаю, сам не щупал. Давай попросим товарищей SBorovkov или Чипа!

Так по таймеру вопрос какой?

У меня накрылась ардуно, вчера еще работала нормально. сейчас подключаю "устройство не опознано"

Проверил напряжение между GND и ногой 5V там напряжение 3.6.

Так что пока приедет новое ардуно откладываю проект :(

Цитата:

---

Сообщение от Chip

Так по таймеру вопрос какой?

---

По таймеру я не понял, какие действия нужно выполнить чтобы установить таймер. то что я привел это вырезал из той темы которую ты дал.

Можешь написать семпл простой как установить и настроить таймер "2"

пощупай все детали на ардуине. Если все детали холодные, то дело в диоде по питанию, наверное. Там 5 вольт бирется с usb тупо через диод, насколько я помню. Диод стоит копейки.

По таймеру - выглядит все правильно. Проверить пока не могу - на работе сижу. Можно взять готовую библиотеку таймера к ардуине и ею пользоваться.

Немного по исследовал протокол.

4я и 5я тетрада указывает расстояние в сантиметрах до препятствия

Детект препятствия

PHP код:

---

Дисплей показывает расстояние 0.0

1111 1000 0000 0001 1010 0 == 26 см
1111 1000 1011 1111 1111 0
1111 1000 1001 1111 1111 0
1111 1000 1010 1111 1111 0

Дисплей показывает расстояние 0.8

1111 1000 0000 0101 0000 0  == 80 см
1111 1000 1011 1111 1111 0
1111 1000 1001 1111 1111 0
1111 1000 1010 1111 1111 0

Дисплей показывает расстояние 1.0

1111 1000 0000 0110 0001 0  == 97 см
1111 1000 1011 1111 1111 0
1111 1000 1001 1111 1111 0
1111 1000 1010 1111 1111 0

Дисплей показывает расстояние 1.1
1111 1000 0000 0110 1110 0 == 110 см
1111 1000 1011 1111 1111 0
1111 1000 1001 1111 1111 0
1111 1000 1010 1111 1111 0 


---

Цитата:

---

Сообщение от SBorovkov

пощупай все детали на ардуине. Если все детали холодные, то дело в диоде по питанию, наверное. Там 5 вольт бирется с usb тупо через диод, насколько я помню. Диод стоит копейки.

---

Все детали холодные, не походу стабилизатор. Я коротнул 5 вольт на землю (сейчас припоминаю)

Цитата:

---

Сообщение от SBorovkov

...Можно взять готовую библиотеку таймера к ардуине и ею пользоваться.

---

Можеш дать наводку ? Я чейто не нашел.

если питаешь от USB, то стабилизатор не участвует. Там стоит выбор питания - либо через usb либо через КРЕН. У кого больше, тот и питает :-).

Поэтому померяй напряжение на входе в arduino USB и на выводе 5В. Если напряжение на USB нормальное, ищи выбитый диод по питанию.

таймер - http://www.arduino.cc/playground/Code/Timer1

Работа двигается потихоньку :) осталось решить два вопроса

1. Это у меня не работает функция Serial.Write(), приходится использовать Serial.print(), вот что она выводит.
1е число содержит бит-флаг-- есть препятствие и номер датчика
2е число расстояние до препятствия в сантиметрах

PHP код:

---

137 255 0 0 ------
------
138 255 0 0 ------
------
136 255 0 0 ------
------
139 255 0 0 ------
------
137 255 0 0 ------
------ 


---

2. Адаптировать плугин из центрифуги под ардуно.


Все оказалось настолько просто что у меня возник вопрос почему ни кто это ранее не делал ? :)

Собственно скетч.

PHP код:

---

#include <TimerOne.h>

#define LEDPIN 13        // Вывод светодиода
#define BTNPIN 2 

#define BUFFER_LENGTH 100

volatile uint16_t startImpuls;
volatile uint16_t lengthImpuls;
volatile uint16_t timerCount=0;

byte buffPos = 0;
byte Buffer[BUFFER_LENGTH];

byte packet[4];
byte posInPacket=0;

byte startBYTE = 15;

void setup()
{  /*
    LOW — вызов прерывания всякий раз, когда на порту низкий уровень напряжения;
    CHANGE – прерывание вызывается при изменении значения на входе;
    RISING – вызов прерывания при изменении уровня напряжения с низкого (LOW) на высокое(HIGH)
    FALLING – вызов прерывания при изменении уровня напряжения с высокого (HIGH) на низкое (LOW)
  */
  startImpuls=0;
  lengthImpuls=0;
  
  pinMode(BTNPIN, INPUT);  
  
  for(int i=0; i< BUFFER_LENGTH; i++)
    Buffer[i]=0;
    
  Serial.begin(115200);
  
  Timer1.initialize(20);
  Timer1.attachInterrupt(callback);  // attaches callback() as a timer overflow interrupt

  attachInterrupt(0, fireUp, RISING);
}
void callback() {  timerCount++; }

void loop()
{
  if (lengthImpuls > 0)
  {
    uint16_t temp=0;
    uint16_t li = lengthImpuls;
    lengthImpuls=0;
    
    //--------------------------//
    // получена приамбула "1 1 1 1"
    if (li >50 && li <60)
    {
       posInPacket =0;
    }
    // Расчитываю позицию массиве
    temp = posInPacket / 8;
    uint16_t bitPos = posInPacket;
    // Разворачиваю позицию для метода bitSet(x,n)
    bitPos = 7 - bitPos;
    if (bitPos >= 8)
    {
      bitPos =  posInPacket - (8*temp);
    }
   
    // Получен "0"
    if (li >4 && li <6)
    {
      posInPacket ++;
    }

     // Получен "1"
    else if (li >10 && li <15)
    {
      bitSet(packet[temp],bitPos);
      posInPacket ++;
    }
    //digitalWrite(13,LOW);
    // Отправить пакет "большему брату"
    if (posInPacket > 15)
    {
      detachInterrupt(0);
      Serial.println("------");

      for(int i=0; i<4; i++)
      {
        Serial.print(packet[i], DEC);
        Serial.print(" ");
        packet[i]=0;
      }
      Serial.println("------");
      posInPacket = 0;
      attachInterrupt(0, fireUp, RISING);
    }
    
    //--------------------------//
  }
 }

// Функция обработки прерывания на подъем
void fireUp()
{

  detachInterrupt(0);
  startImpuls = timerCount;
  attachInterrupt(0, fireDown, FALLING);
}

// Функция обработки прерывания на подъем
void fireDown()
{
  detachInterrupt(0);
  lengthImpuls = timerCount - startImpuls;
  startImpuls=0;
  timerCount=0;
  attachInterrupt(0, fireUp, RISING);
} 


---

И так первую проблему решил :)

Принимаются советы по улучшению/оптимизации скетча

PHP код:

---

#include <TimerOne.h>

#define LEDPIN 13        // Вывод светодиода
#define BTNPIN 2 

volatile uint16_t startImpuls;
volatile uint16_t lengthImpuls;
volatile uint16_t timerCount=0;

//byte buffPos = 0;

byte packet[2];
byte posInPacket=0;

byte startBYTE = 15;

void setup()
{  /*
    LOW — вызов прерывания всякий раз, когда на порту низкий уровень напряжения;
    CHANGE – прерывание вызывается при изменении значения на входе;
    RISING – вызов прерывания при изменении уровня напряжения с низкого (LOW) на высокое(HIGH)
    FALLING – вызов прерывания при изменении уровня напряжения с высокого (HIGH) на низкое (LOW)
  */
  startImpuls=0;
  lengthImpuls=0;
  
  pinMode(BTNPIN, INPUT);  
  
  Serial.begin(115200);
  
  Timer1.initialize(20);
  Timer1.attachInterrupt(callback);  // attaches callback() as a timer overflow interrupt

  attachInterrupt(0, fireUp, RISING);
}
void callback() {  timerCount++; }

void loop()
{
  if (lengthImpuls > 0)
  {
    uint16_t temp=0;
    uint16_t li = lengthImpuls;
    lengthImpuls=0;
    
    //--------------------------//
    // получена приамбула "1 1 1 1"
    if (li >50 && li <60)
    {
       posInPacket =0;
    }
    // Расчитываю позицию массиве
    temp = posInPacket / 8;
    uint16_t bitPos = posInPacket;
    // Разворачиваю позицию для метода bitSet(x,n)
    bitPos = 7 - bitPos;
    if (bitPos >= 8)
    {
      bitPos =  posInPacket - (8*temp);
    }
   
    // Получен "0"
    if (li >4 && li <6)
    {
      posInPacket ++;
    }

     // Получен "1"
    else if (li >10 && li <15)
    {
      bitSet(packet[temp],bitPos);
      posInPacket ++;
    }
    //digitalWrite(13,LOW);
    // Отправить пакет "большему брату"
    if (posInPacket > 15)
    {
      detachInterrupt(0);
     
     // Если есть препятствие тогда посылаем пакет
     if ((packet[0] & 8) == 0)
        Serial.write(packet,2);
      
      // сбрасываю буффер
      packet[0] = 0;
      packet[1] = 0;
      
      posInPacket = 0;
      
      attachInterrupt(0, fireUp, RISING);
    }
    
    //--------------------------//
  }
 }

// Функция обработки прерывания на подъем
void fireUp()
{

  detachInterrupt(0);
  startImpuls = timerCount;
  attachInterrupt(0, fireDown, FALLING);
}

// Функция обработки прерывания на подъем
void fireDown()
{
  detachInterrupt(0);
  lengthImpuls = timerCount - startImpuls;
  startImpuls=0;
  timerCount=0;
  attachInterrupt(0, fireUp, RISING);
} 


---

http://img517.imageshack.us/img517/1479/park1.png

Все основную работу сделал. :) теперь надо оптимизировать

Молодец, поздравляю! Теперь нужно в боевых условиях испытывать.
Плагин какой взял, переделывал его?

Плагин тот что в центрифуге. до боев еще рано , надо код оптимизировать.

Молодец !!!

oops1, класс!!! :)

P.S.
Извиняюсь за флуд. Не удержался. :o

Цитата:

---

Сообщение от oops1

2. Парктронник китайского производства

---

oops1, а можно точнее сказать модель парктронника? А то меня тут спрашивают. :)

Цитата:

---

Сообщение от St@rz

oops1, а можно точнее сказать модель парктронника? А то меня тут спрашивают. :)

---

Внимательней прочитай сообщение в шапке.

Цитата:

---

Все основную работу сделал. теперь надо оптимизировать

---

Плагин для CF правил или под него подстроился?